MemberwiseClone Method (A shallow copy of the current Object.)

The MemberwiseClone method creates a shallow copy by creating a new object, and then copying the nonstatic fields of the current object to the new object. If a field is a value type, a bit-by-bit copy of the field is performed. If a field is a reference type, the reference is copied but the referred object is not; therefore, the original object and its clone refer to the same object.

For example, consider an object called X that references objects A and B. Object B, in turn, references object C. A shallow copy of X creates new object X2 that also references objects A and B. In contrast, a deep copy of X creates a new object X2 that references the new objects A2 and B2, which are copies of A and B. B2, in turn, references the new object C2, which is a copy of C. The example illustrates the difference between a shallow and a deep copy operation.

There are numerous ways to implement a deep copy operation if the shallow copy operation performed by the MemberwiseClone method does not meet your needs. These include the following:

• Call a class constructor of the object to be copied to create a second object with property values taken from the first object. This assumes that the values of an object are entirely defined by its class constructor.
• Call the MemberwiseClone method to create a shallow copy of an object, and then assign new objects whose values are the same as the original object to any properties or fields whose values are reference types. The DeepCopy method in the example illustrates this approach.
• Serialize the object to be deep copied, and then restore the serialized data to a different object variable.
• Use reflection with recursion to perform the deep copy operation.
  
  
  
  
  
  Examples
  
  
  
  
  The following example illustrates the MemberwiseClone method. It defines a ShallowCopy method that calls the MemberwiseClone method to perform a shallow copy operation on a Person object. It also defines a DeepCopy method that performs a deep copy operation on a Person object.
  
  
  
  

  
  
  

  Public Class IdInfo
      Public IdNumber As Integer
  
      Public Sub New(IdNumber As Integer)
          Me.IdNumber = IdNumber
      End Sub
  End Class
  
  Public Class Person 
      Public Age As Integer
      Public Name As String
      Public IdInfo As IdInfo
  
      Public Function ShallowCopy() As Person
         Return DirectCast(Me.MemberwiseClone(), Person)
      End Function
  
      Public Function DeepCopy() As Person
         Dim other As Person = DirectCast(Me.MemberwiseClone(), Person) 
         other.IdInfo = New IdInfo(Me.IdInfo.IdNumber)
         Return other
      End Function
  End Class
  
  Module Example
     Public Sub Main()
          ' Create an instance of Person and assign values to its fields.
          Dim p1 As New Person()
          p1.Age = 42
          p1.Name = "Sam"
          p1.IdInfo = New IdInfo(6565)
  
          ' Perform a shallow copy of p1 and assign it to p2.
          Dim p2 As Person = DirectCast(p1.ShallowCopy(), Person)
  
          ' Display values of p1, p2
          Console.WriteLine("Original values of p1 and p2:")
          Console.WriteLine("   p1 instance values: ")
          DisplayValues(p1)
          Console.WriteLine("   p2 instance values:")
          DisplayValues(p2)
          Console.WriteLine()
  
          ' Change the value of p1 properties and display the values of p1 and p2.
          p1.Age = 32
          p1.Name = "Frank"
          p1.IdInfo.IdNumber = 7878
          Console.WriteLine("Values of p1 and p2 after changes to p1:")
          Console.WriteLine("   p1 instance values: ")
          DisplayValues(p1)
          Console.WriteLine("   p2 instance values:")
          DisplayValues(p2)
          Console.WriteLine()
  
          ' Make a deep copy of p1 and assign it to p3.
          Dim p3 As Person = p1.DeepCopy()
          ' Change the members of the p1 class to new values to show the deep copy.
          p1.Name = "George"
          p1.Age = 39
          p1.IdInfo.IdNumber = 8641
          Console.WriteLine("Values of p1 and p3 after changes to p1:")
          Console.WriteLine("   p1 instance values: ")
          DisplayValues(p1)
          Console.WriteLine("   p3 instance values:")
          DisplayValues(p3)
     End Sub
  
      Public Sub DisplayValues(p As Person)
          Console.WriteLine("      Name: {0:s}, Age: {1:d}", p.Name, p.Age)
          Console.WriteLine("      Value: {0:d}", p.IdInfo.IdNumber)
      End Sub
  End Module
  ' The example displays the following output:
  '       Original values of m1 and m2:
  '          m1 instance values:
  '             Name: Sam, Age: 42
  '             Value: 6565
  '          m2 instance values:
  '             Name: Sam, Age: 42
  '             Value: 6565
  '       
  '       Values of m1 and m2 after changes to m1:
  '          m1 instance values:
  '             Name: Frank, Age: 32
  '             Value: 7878
  '          m2 instance values:
  '             Name: Sam, Age: 42
  '             Value: 7878
  '       
  '       Values of m1 and m3 after changes to m1:
  '          m1 instance values:
  '             Name: George, Age: 39
  '             Value: 8641
  '          m3 instance values:
  '             Name: Frank, Age: 32
  '             Value: 7878
  
  

  In this example, the Person.IdInfo property returns an IdInfo object. As the output from the example shows, when a Person object is cloned by calling the MemberwiseClonemethod, the cloned Person object is an independent copy of the original object, except that they share the same Person.IdInfo object reference. As a result, modifying the clone's Person.IdInfo property changes the original object's Person.IdInfo property. On the other hand, when a deep copy operation is performed, the cloned Person object, including its Person.IdInfo property, can be modified without affecting the original object.